Ajax Paper Company

    {  Ajax.mpl  }

    {  GAMS Model Library, http://www.gams.com/modlib/libhtml/ajax.htm  }

    {  Ajax Paper Company Production Schedule, Production Planning, Size: 7 x 12 }


TITLE
   Ajax;

INDEX
    m := (machine_1, machine_2, machine_3);
    g := (bond_20wt, bond_25wt, bond_Cext, tissue_wrp);

DATA

    Prate[g,m] := (
 !                machine_1 machine_2 machine_3
 {bond_20wt}       53,        52,        49,
 {bond_25wt}       51,        49,        44,
 {bond_Cext}       52,        45,        47,
 {tissue_wrp}      42,        44,        40);

    Pcost[g,m] := (
 !                machine_1 machine_2 machine_3
 {bond_20wt}       76,        75,        73,
 {bond_25wt}       82,        80,        78,
 {bond_Cext}       96,        95,        92,
 {tissue_wrp}      72,        71,        70);

    Demand[g]   := (30000, 20000, 12000, 8000);
    Price[g]    := (77, 81, 99, 105);
    Avail[m]    := (672, 600, 480);

VARIABLE
    Outp[g,m];


MODEL

    MAX Profit = SUM(g: Demand * Price) - SUM(g,m: Pcost * Outp);

SUBJECT TO

    Cap[m]:  SUM(g: Outp / Prate) <= Avail;

    Dem[g]:  SUM(m: Outp) = Demand;

END