Planning the Production of FiberGlass

    {  Exmpl8.5-1_FiberGlass.mpl  }

    {  Applications of Optimization with Xpress-MP  }

    {  Chapter 8.5,  Planning the Production of FiberGlass,  Size: 12x11,  Page 156 }


TITLE
    FiberGlasss;

INDEX
    node := 1..12;
    node2 := node;
    sink[node] := (2,4,6,8,10,12);
    source[node] := NOT sink;

DATA
    Cost[node,node2] := [1, 2,5,
                         3, 4,8,
                         5, 6,6,
                         7, 8,6,
                         9,10,7,
                        11,12,6,
                         2, 4,0.2,
                         4, 6,0.3,
                         6, 8,0.2,
                         8,10,0.25,
                        10,12,0.3];
    Cap[node,node2] := [ 1, 2,140,
                         3, 4,100,
                         5, 6,110,
                         7, 8,100,
                         9,10,120,
                        11,12,100];

    Demand[sink] := (100,120,100, 90,120,110);


VARIABLE
    Flow[node,node2] WHERE (Cost > 0);

MODEL

    MIN TotalCosts = SUM(node,node2: Cost * Flow);

SUBJECT TO

    ASatisfyDemand[node IN sink] -> DEM:
      IIF (node<last(node), Flow[node,node2:=node+2], 0)
    =
      IIF (node>2, Flow[node:=node-2,node2:=node], 0)
    + Flow[node:=node-1,node2:=node] - Demand;

    ProductionCapability[node,node2] WHERE (Cap > 0)-> SBAL:
       Flow <= Cap;

END