Planning the Production of Electronic Components

    {  Exmpl8.4-2_ElectronicComponents.mpl  }

    {  Applications of Optimization with Xpress-MP  }

    {  Chapter 8.4,  Planning the Production of Electronic Components,  Size: 33x58,  Page 153 }


TITLE
   ElectronicComponents;

DATA
    NT := 6;

INDEX
    month := 1..NT;
    prod := 1..4;

DATA
    Dem[prod,month] := 100(15,30,20,40,20,25,
                           13, 8, 8,10,11, 9,
                           22,15,29,18,12,21,
                           14,16,15,10,11,12);
    Cprod[prod] := (20,25,10,15);
    Cstock[prod] := (0.4,0.5,0.3,0.3);
    Cadd := 1;
    Cred := 0.5;
    Istock[prod] := (10,0,0,0);
    Fstock[prod] := (50,10,10,10);

VARIABLE
    Produce[prod,month];
    Store[prod,month];
    Reduce[month];
    Add[month];

MODEL

    MIN TotalCosts = SUM(prod,month: Cprod * Produce + Cstock * Store) +
                     SUM(month=2..NT: Cred * Reduce + Cadd * Add);

SUBJECT TO

    StockBalanceInit[prod,month=1] -> SBALI:
      Store = Istock + Produce - Dem;

    StockBalance[prod,month>1] -> SBAL:
      Store = Store[month-1] + Produce - Dem;

    ProductionLevel[month>1] -> PLEV:
      SUM(prod: Produce - Produce[month-1]) = Add - Reduce;

    FinalSotckLevel[prod] -> FLEV:
      Store[month:=NT] >= Fstock;


END