Multi-Period Planning

   {  Exmpl2.6_MultiPeriod.mpl  }

   {  Murty, Operations Research, Determining Optimization Models  }

   {  Chapter 2,  Example 2.6,  Production Planning,  Size: 6x19,  Page 40  }


TITLE
    MultiPeriodProdPlanning;

INDEX
    period := 1..6;

DATA
    ProdCost[period]     := (20, 25, 30, 40, 50, 60);
    ProdCapacity[period] := (1500, 2000, 2200, 3000, 2700, 2500);
    Demand[period]       := (1100, 1500, 1800, 1600, 2300, 2500);
    SellingPrice[period] := (180, 180, 250, 270, 300, 320);
    InventoryCost        := 2;
    InitialStock         := 500;
    FinalStock           := 500;

VARIABLES
    Produce[period] -> Prod;
    Inventory[period=0..6] -> Invt;
    Sales[period] -> Sale;

MACROS
    TotalRevenue  := SUM(period: SellingPrice * Sales);
    TotalProdCost := SUM(period: ProdCost * Produce);
    TotalInvtCost := SUM(period: InventoryCost * Inventory);
    TotalCost     := TotalProdCost + TotalInvtCost;

MODEL

    MAX NetProfit = TotalRevenue - TotalCost;

SUBJECT TO
    InventoryBalance[period] -> InvtBal:

        Inventory  =  Inventory[period-1] + Produce - Sales;

BOUNDS
    Produce  <=  ProdCapacity;

    Sales  <=  Demand;

    Inventory[period=0]  =  InitialStock;
    Inventory[period=6]  =  FinalStock;

END