Effeciency of Hospitals

    {  Exmpl15.6-1_HospitalEfficiency.mpl  }

    {  Applications of Optimization with Xpress-MP  }

    {  Chapter 15.6,  Efficiency of Hospitals,  Size: 15x12,  Page 332 }


TITLE
    HospitalEfficiency;

INDEX
    hosp := 1..4;
    serv := (admission,consultation,doctor,nursing);
    res  := (nonmed,general,beds);

DATA
    SelHosp := 2;
    Indserv[serv,hosp] := (30.12,18.54,20.88,10.42,
                           13.54,14.45, 8.52,17.74,
                              13,    7,    8,   26,
                              79,   55,   47,   50);
    Indres[res,hosp]   := (   90,    87,   51,   66,
                           38.89,109.48,40.43,48.41,
                              34,    33,   20,   33);

VARIABLE
    Eff;
    Coef[hosp];
    Fserv[serv];
    Fres[res];

MODEL

    MIN Eff;

SUBJECT TO

    DEACoefficients -> DEAC:
        SUM(hosp: Coef) = 1;

    ServicRelation[serv] -> RELS:
        SUM(hosp: Indserv * Coef) = Fserv;

    ResourceRelation[res] -> RELR:
        SUM(hosp: Indres * Coef) = Fres;

    ServiceLimits[hosp=SelHosp,serv] -> SLIM:
        Fserv >= Indserv;

    ResourceLimits[hosp=SelHosp,res] -> SLIM:
        Fres <= Indres * Eff;

END