Social Accounting

    {  sambal.mpl   }

    {  GAMS Model Library, http://www.gams.com/modlib/libhtml/sambal.htm  }

    {  Social Accounting Matrix Balancing Problem,  NLP,  Size: 10x15  }



TITLE
    Sambal;

OPTIONS
    ModelType=Nonlinear
    ParserType=Extended

INDEX
    i := (lab, h1, h2, p1, p2);
    j := i;

DATA
    M := 100000;
    Xb[i,j] := (0, 15,  3,130, 80,
                0,  0,  0,  0,  0,
                0,  0,  0,  0,  0,
                0, 15,130,  0, 20,
                0, 25, 40, 55,  0);
    Tb[i] := (220, M,M,190,105);
    Tw[i] := (1,0,0,1,1);
    Xw[i,j] := (0,1,1,1,1,
                0,0,0,0,0,
                0,0,0,0,0,
                0,1,1,0,1,
                0,1,1,1,0);

VARIABLES
    X[i,j] INITIAL Xb;
    T[i] INITIAL Tw;

MODEL

    MIN Dev = SUM(i,j: Xw*SQR(Xb-X)/Xb WHERE Xw > 0.5)
            + SUM(i: Tw*SQR(Tb-T)/Tb WHERE Tw > 0.5);

SUBJECT TO

     RBal[i]:   T = SUM(j: X WHERE Xb > 0);

     CBal[j]:   T = SUM(i: X WHERE Xb > 0);

BOUNDS
     -M <= X <= M;
     -M <= T <= M;

END