Production of Electricity

    {  Exmpl6.6-1_electprod.mpl  }

    {  Applications of Optimization with Xpress-MP  }

    {  Chapter 6.6,  Production of Electricity,  Size: 70x84,  Page 106 }

TITLE
    ElectricityProduction;

DATA
    Nt := 7;

INDEX
    time := 1..Nt;
    type := 1..4;

DATA
    Len[time] := (6,3,3,2,4,4,2);
    Dem[time] := 1000(12, 32, 25, 36, 25, 30,18);
    Pmin[type] := (750,1000,1200,1800);
    Pmax[type] := (1750,1500,2000,3500);
    Cstart[type] := (5000,1600,2400,1200);
    Cmin[type] := (2250,1800,3750,4800);
    Cadd[type] := (2.7,2.2,1.8,3.8);
    Avail[type] := (10,4,8,3);

VARIABLE
    Start[type,time];
    Work[type,time];
    Padd[type,time];

MODEL

    MIN TotalCost = SUM(type,time: Cstart * Start + Len * (Cmin * Work + Cadd * Padd));

SUBJECT TO

    NumberGeneratorsStarted[time=1,type] -> GNSTR:
      Start >= Work - Work[time:=Nt];
    NumberGeneratorsStarteda[time>1,type] -> GNSTR:
      Start >= Work - Work[time-1];

    ProdLimit[type,time] -> PWMN:
      Padd <= Work * Pmax - Work * Pmin;

    MeetDemand[time] -> MDEM:
      SUM(type: Pmin * Work + Padd) >= Dem;

    SecurityReserve[time] -> SECR:
      SUM(type: Pmax * Work) >= 1.2 * Dem;

BOUNDS
    Work <= Avail;

INTEGER
    Work;

END