Production Planning & Transportation

    {  Exmpl4.3-1_Prod_Transport.mpl  }

    {  AMPL A Modeling Language for Mathematical Programming, 2nd Edition }

    {  Chapter 4.3,  Production Planning & Transportation,  Size: 33x72,  Page 63 }


TITLE
    Prod_Transport;

INDEX
    origin := (gary,clev,pitt);
    dest   := (fra,det,lan,win,stl,fre,laf)
    prod   := (bands,coils,plate);

DATA
    Avail[origin] := (20,15,20);
    Demand[prod,dest]   := (300,300,100, 75,650,225,250,
                            500,750,400,250,950,850,500,
                            100,100,  0, 50,200,100,250);
    Rate[prod,origin]     := (200,190,260,
                              140,130,160,
                              160,160,170);
    MakeCost[prod,origin] := (180,190,190,
                              170,170,180,
                              180,185,185);
    TransCost[prod,origin,dest] := (30,10, 8,10,11,71, 6,
                                    22, 7,10, 7,21,82,13,
                                    19,11,12,10,25,83,15,
                                    39,14,11,14,16,82, 8,
                                    27, 9,12, 9,26,95,17,
                                    24,14,17,13,28,99,20,
                                    41,15,12,16,17,86, 8,
                                    29, 9,13, 9,28,99,18,
                                    26,14,17,13,31,104,20);

VARIABLE
    Make[origin,prod];
    Trans[origin,dest,prod];

MODEL

    MIN TotalCost = SUM(origin,prod: MakeCost * Make) +
                    SUM(origin,dest,prod: TransCost * Trans);

SUBJECT TO

    Timing[origin] -> TIM:
         SUM(prod: 1 / Rate * Make) <= Avail;

    Supplying[origin,prod] -> SUP:
         SUM(dest: Trans) = Make;

    Meetdemand[dest,prod] -> DEM:
         SUM(origin: Trans) = Demand;

END