Distribution Unlimited

   {  Exmpl3.4-6_DistrUnlimited.mpl  }

   {  Hillier and Lieberman, Introduction to Operations Research, 9th ed.  }

   {  Chapter 3.4,  Example 6,  Transportaion,  Size: 7x7,  Page 58  }


TITLE
    DistributionUnlimited;

INDEX
    loc    := (F1, F2, DC, W1, W2);
    source := loc;
    dest   := loc;

DATA
    ShipCost[source, dest] := [F1, F2, 200,
                               F1, DC, 400,
                               F1, W1, 900,
                               F2, DC, 300,
                               DC, W2, 100,
                               W1, W2, 300,
                               W2, W1, 200];
    Supply[loc] := [F1, 50,
                    F2, 40];

    Demand[loc] := [W1, 30,
                    W2, 60];

    MaxFlow[source, dest] := [F1, F2, 10,
                              DC, W2, 80];
VARIABLES
    Ship[source, dest]  WHERE (ShipCost);

MODEL

    MIN TotalCost  =  SUM(source, dest:  ShipCost * Ship);

SUBJECT TO

    NetFlow[loc] :

        SUM(source: Ship[dest:=loc]) + Supply
      =
        SUM(dest: Ship[source:=loc]) + Demand;


    MaxShipment[source, dest] WHERE (MaxFlow):

        Ship  <=  MaxFlow;
END