Transportation

    {  Exmpl18.4-1_NLPTransport.mpl  }

    {  AMPL A Modeling Language for Mathematical Programming, 2nd Edition }

    {  Chapter 18.4,  Transportation, Non Linear,  Size: 10x21,  Page 404 }



TITLE
    NLPTransport;

Option
    ModelType=Nonlinear
    ParserType=Extended

INDEX
    origin := (gary,clev,pitt);
    dest   := (fra,det,lan,win,stl,fre,laf)

DATA
    Supply[origin] := (1400,2600,2900);
    Demand[dest]   := ( 900,1200, 600, 400,1700,1100,1000)
    Rate[origin,dest] := (39,14,11,14,16,82, 8,
                          27, 9,12, 9,26,95,17,
                          24,14,17,13,28,99,20);
    Limit[origin,dest] := 100 * ( 5,10,10,10, 8, 5,10,
                                  5, 8, 8, 8, 5, 5,10,
                                  8, 6, 6, 6, 5, 5, 9);

VARIABLE
    Trans[origin,dest] INITIAL 0;
 !   IntTrans[origin,dest];
 !   IntTrans2[origin,dest];

MODEL

    MIN TotalCost = SUM(origin,dest: Rate * Trans / (1 - Trans / Limit));


SUBJECT TO

    Supplying[origin] -> SUP:
         SUM(dest: Trans) = Supply;

    Meetdemand[dest] -> DEM:
         SUM(origin: Trans) = Demand;

BOUNDS
    0 <= Trans <= Demand;
    0 <= Trans <= 0.9999 * Limit;

END