Planning the personnel at a construction site

    {  Exmpl14.6-1_ConstructionPersonnel.mpl  }

    {  Applications of Optimization with Xpress-MP  }

    {  Chapter 14.6,  Planning the Personnel at a Construction Site,  Size: 36x30,  Page 306 }


TITLE
    ConstructionPersonnel;

DATA
    Ifirst := 3;
    Ilast  := 8;

INDEX
    month := Ifirst..Ilast;

DATA
    Carr   := 100;
    Cleave := 160;
    Cover  := 200;
    Cunder := 200;
    Nstart := 3;
    Nfinal := 3;
    Req[month] := (4,6,7,4,6,2);

VARIABLE
    Onsite[month];
    Arrive[month];
    Leave[month];
    VOver[month];
    Under[month];

MODEL

    MIN Cost = SUM(month: Carr * Arrive + Cleave * Leave + Cover * VOver + Cunder * Under);

SUBJECT TO

    SatisfyWorkerNeeds[month] -> SWN:
        Onsite - VOver + Under = Req;

    Balance[month=Ifirst] -> BAL:
        Onsite = Nstart + Arrive;
    BalanceA[month>Ifirst] -> BALA:
        Onsite = Onsite[month-1] - Leave[month-1] + Arrive;
    BalanceB[month] -> BALB:
        Nfinal = Onsite[month:=Ilast] - Leave[month:=Ilast];

    LimitationsDep[month] -> LDEP:
        Leave <= 1/3 * Onsite;
    LimitationsUnderStaf[month] -> LUS:
        Under <= 1/4 * Onsite;
    LimitationsArrival[month] -> LAR:
        Arrive <= 3;

INTEGER
    Onsite;
    Arrive;
    Leave;
    VOver;
    Under;

END