Airline hub location

    {  Exmpl11.4-1_HubLocation.mpl  }

    {  Applications of Optimization with Xpress-MP  }

    {  Chapter 11.4, Airline Hub Location,  Size: 2629x1302,  Page 224 }


TITLE
    HubLocation;

INDEX
    city := 1..6;
    city2 := city;
    city3 := city;
    city4 := city;

DATA
    Nhub := 2;
    Dist[city,city2] := (  0, 945, 605,4667,4749,4394,
                         945,   0, 866,3726,3806,3448,
                         605, 866,   0,4471,4541,4152,
                        4667,3726,4471,   0, 109, 415,
                        4749,3806,4541, 109,   0, 431,
                        4394,3448,4152, 415, 431,   0);
    Factor := 0.2; !in book they used 0.8 to get solution

    Cost[city,city2,city3,city4] := Dist[city,city2:=city3] + Factor * Dist[city:=city3,city2:=city4] + Dist[city:=city4,city2];
    Quant[city,city2] := (   0, 500,1000, 300, 400,1500,
                          1500,   0, 250, 630, 360,1140,
                           400, 510,   0, 460, 320, 490,
                           300, 600, 810,   0, 820, 310,
                           400, 100, 420, 730,   0, 970,
                           350,1020, 260, 580, 380,   0);

VARIABLE
    Flow[city,city2,city3,city4];
    Hub[city];

MODEL

    MIN TotalCost = SUM(city,city2,city3,city4: Quant * Cost * Flow);

SUBJECT TO

    NumberofHubs -> NHUB:
        SUM(city: Hub) = Nhub;

    OneHub2HubConnection[city,city2] -> H2H:
        SUM(city3,city4: Flow) = 1;

    RelationFlowHub[city,city2,city3,city4] -> REL:
        Flow <= Hub[city:=city3];
    RelationFlowHubA[city,city2,city3,city4] -> RELA:
        Flow <= Hub[city:=city4];

BINARY
    Hub;
    Flow;

END