Combining different modes of transport

    {  Exmpl10.5-1_CombinedTransport.mpl  }

    {  Applications of Optimization with Xpress-MP  }

    {  Chapter 10.5,  Fleeting Planning for Vans,  Size: 34x39,  Page 204 }


TITLE
    CombinedTransport;

DATA
    NL := 4;

INDEX
    leg := 1..NL;
    mode := (rail,road,air);
    mode2 := mode;

DATA
    Ctran[mode,leg]  := (30,25,40,60,
                         25,40,45,50,
                         40,20,50,45);
    Cchg[mode,mode2] := ( 0, 5,12,
                          8, 0,10,
                         15,10, 0);

VARIABLE
    TUse[mode,leg];
    Change[mode,mode2,leg=1..NL-1];

MODEL

    MIN TotalCost = SUM(mode,leg: Ctran * TUse) +
                    SUM(mode,mode2,leg=1..NL-1: Cchg * Change);

SUBJECT TO

    OneModeperLeg[leg] -> OML:
        SUM(mode: TUse) = 1;

    ChangeOrMaintainMode[leg=1..NL-1] -> CML:
        SUM(mode,mode2: Change) = 1;

    RelationModeChanges[mode,mode2,leg=1..NL-1] -> RMC:
        TUse + TUse[mode:=mode2,leg+1] >= 2 * Change;

BINARY
    TUse;
    Change;

END